Ok..maybe I will change the varnised finish used on the capstan bars, but
the capstan is finished. I know the star is off center. When the star was
centered, it just didn't look right to me...too perfect. I set a flag that
determines when capstan bars are used. Normally they would be stowed away
unless the anchor was being raised.

I have to express my thanks to this community. It is the feed back and
encouragement that you have generously given to me that has brought my work
to this level. I hope that I can return something in kind to the community
in the future.

I used low radiosity settings, so please over look the poor quality of the
lighting.

Thanks,

Tim



All textures are proceedural. I modified and made corrections to the macro
used to generate the worn painted wood finish. Here is the new one:


RGB  is the RGB vector that describes the color being used.

WearFlatH and WearFlatV describe the amount of wear that is applied to the
horizontal and vertical surfaces.

WearEdge determines the wear applied to the rounded edges.

Norm is the normal used by the slope statement

Rot is the vector used to rotate the texture. The texture is rotated prior
to being translated.

Tran is the vector used to translate the texture

Scale is the vector used to scale the texture.


#macro WornWoodS(RGB,WearFlatH,WearFlatV,WearEdge,Norm,Rot,Tran,Scale)
        #declare Texture1 =
                texture {
                        pigment {
                            wood
                            turbulence <0.1, 0.5, 1>
                            octaves 5
                            lambda 3.25
                            scale <0.15, .5, 1>
                            rotate <5, 10, 5>
                            translate -x*2

                                color_map {
                                    [0.0 color RGB]
                                    [0.1 color RGB]
                                    [0.1 color 0.8*RGB]
                                    [0.9 color 0.8*RGB]
                                    [1.0 color RGB]
                                }


                        }
                        finish{
                                ambient 0
                                phong 0.05
                                phong_size 250

                        }
                }

        #declare TWood1 =
                        texture{T_Wood7}
                        texture {
                                pigment{color rgbt <255, 155, 23,
0.999999*256>/256*0.25}
                        }
        #declare TWood2 =
                        texture{T_Wood7}
                        texture {
                                pigment{color rgbt <255, 155,
23,1.5*256>/256*0.45}
                        }

        #declare PaintedWood1 =

          texture{
            bozo
            texture_map{
              [0 TWood1]
              [WearFlatH TWood2]
              [WearFlatH+0.1 Texture1]
              [1.0 Texture1]
            }

            warp{turbulence 0.2}
            scale <0.25,0.25,50>
          }

        #declare PaintedWood2 =

        texture{
                bozo
                texture_map{
                        [0 TWood1]
                        [WearEdge TWood2]
                        [WearEdge+0.1 Texture1]
                        [1.0 Texture1]
                }

                warp{turbulence 0.2}
                scale <0.25,0.25,50>
        }
        #declare PaintedWood3 =

          texture{
            bozo
            texture_map{
              [0 TWood1]
              [WearFlatV TWood2]
              [WearFlatV+0.1 Texture1]
              [1.0 Texture1]
            }

            warp{turbulence 0.2}
            scale <0.25,0.25,50>
          }
         #declare DummyNum =0;

         texture{
                slope { <0,-1,0> }
                    texture_map{
                      [0 PaintedWood1]
                      [0.1 PaintedWood2]
                      [0.4 PaintedWood3]
                      [0.6 PaintedWood3]
                      [0.9 PaintedWood2]
                      [1.0 PaintedWood1]
                    }
                warp{turbulence 0.2}
                scale Scale
                rotate Rot
                translate Tran
         }



#end

Post a reply to this message

Attachments:
Download 'capstan_080205.jpg' (91 KB)

Preview of image 'capstan_080205.jpg'